Konfigurationsscript mittels TFTP auslesen

Fragen zur LANCOM Management Windows Software/ LANtolls: LANconfig, LANmonitor, WLANmonitor.

Moderator: Lancom-Systems Moderatoren

Antworten
itf009
Beiträge: 5
Registriert: 09 Mai 2018, 16:17

Konfigurationsscript mittels TFTP auslesen

Beitrag von itf009 »

Hallo Leute,


ich versuche gerade mittels Tftp das ConfigScript aus meinem Lancom Router auszulesen und direkt unter laufwerk D:\ zu speichern.

Folgende Befehle habe ich ausprobiert:

tftp 192.168.172.1 get root:test-1234@readscript "D:\dora.lcs"

tftp.exe 192.168.172.1 get test-1234@readscript "D:\dora.lcs"


Momentan erhalte ich nur Timeouts...

Vielen Dank für eure Hilfe

Der Tftp-Client von microsoft wurde aktiviert und TFTP ist im Lancom erlaubt.

Lancom 1781AW/VA
10.12 RU6
Benutzeravatar
Pothos
Moderator
Moderator
Beiträge: 366
Registriert: 09 Feb 2012, 10:26
Wohnort: Jülich

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von Pothos »

Hi itf009,

bisschen spät aber vllt hilft es ja noch. Lass das "@" weg und probier es so:

Code: Alles auswählen

tftp 192.168.172.1 get test-1234readscript "D:\dora.lcs"
Gruß
Pothos
Benutzeravatar
Bernie137
Beiträge: 1700
Registriert: 17 Apr 2013, 21:50
Wohnort: zw. Chemnitz und Annaberg-Buchholz

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von Bernie137 »

Hi,

ich würde es vorziehen, die Konfig mittels plink (putty) auszulesen per ssh:

Code: Alles auswählen

c:\putty\plink.exe -pw GanzGeheim root@192.168.1.1 readscript > c:\putty\script_backups\Router.lcs
c:\putty\plink.exe -pw GanzGeheim root@192.168.1.1 readscript > c:\putty\script_backups\Router.lcf
Damit bekommt man ein hübsches Lancom-Scriptdatei und auch eine LANconfig Datei geliefert. Das Ganze kann man dann noch in ein Script (Batchdatei) packen:

Code: Alles auswählen

@echo off
setlocal
SET plink=C:\putty\plink.exe
SET csvPfad=C:\putty\devices.csv
SET backupPfad=C:\putty\backups
Set day=%DATE:~0,2%
Set mm=%DATE:~3,2%
Set dd=%DATE:~0,2%
Set yyyy=%DATE:~6,4%

for /F "usebackq tokens=1-4 eol=# delims=; " %%i in (%csvPfad%) do (
	%plink% -pw %%l %%k@%%j readscript > "%backupPfad%\%%i_%yyyy%%mm%%dd%.lcs"
	%plink% -pw %%l %%k@%%j readconfig > "%backupPfad%\%%i_%yyyy%%mm%%dd%.lcf")
endlocal
Im Ordner C:\putty legt man eine devices.csv an, in der man dann x-beliebige Geräte abspeichern kann in der Form:

Code: Alles auswählen

#name;ip;user;password
ROUTER1;192.168.1.1;root;GanzGeheim
ROUTER2;192.168.1.2;root;MegaGeheim
AP3;192.168.35.4;root;Passwort
Beim ersten Zugriff muss man nur die SSH-Warnung pro Gerät bestätigen, dann läuft das Script auch im Taskplaner.

Gruß Bernie
Man lernt nie aus.
itf009
Beiträge: 5
Registriert: 09 Mai 2018, 16:17

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von itf009 »

Bernie137 hat geschrieben: 19 Jun 2018, 15:38 Hi,

ich würde es vorziehen, die Konfig mittels plink (putty) auszulesen per ssh:

Code: Alles auswählen

c:\putty\plink.exe -pw GanzGeheim root@192.168.1.1 readscript > c:\putty\script_backups\Router.lcs
c:\putty\plink.exe -pw GanzGeheim root@192.168.1.1 readscript > c:\putty\script_backups\Router.lcf
Damit bekommt man ein hübsches Lancom-Scriptdatei und auch eine LANconfig Datei geliefert. Das Ganze kann man dann noch in ein Script (Batchdatei) packen:

Code: Alles auswählen

@echo off
setlocal
SET plink=C:\putty\plink.exe
SET csvPfad=C:\putty\devices.csv
SET backupPfad=C:\putty\backups
Set day=%DATE:~0,2%
Set mm=%DATE:~3,2%
Set dd=%DATE:~0,2%
Set yyyy=%DATE:~6,4%

for /F "usebackq tokens=1-4 eol=# delims=; " %%i in (%csvPfad%) do (
	%plink% -pw %%l %%k@%%j readscript > "%backupPfad%\%%i_%yyyy%%mm%%dd%.lcs"
	%plink% -pw %%l %%k@%%j readconfig > "%backupPfad%\%%i_%yyyy%%mm%%dd%.lcf")
endlocal
Im Ordner C:\putty legt man eine devices.csv an, in der man dann x-beliebige Geräte abspeichern kann in der Form:

Code: Alles auswählen

#name;ip;user;password
ROUTER1;192.168.1.1;root;GanzGeheim
ROUTER2;192.168.1.2;root;MegaGeheim
AP3;192.168.35.4;root;Passwort
Beim ersten Zugriff muss man nur die SSH-Warnung pro Gerät bestätigen, dann läuft das Script auch im Taskplaner.

Gruß Bernie

DANKEEE !!!!!!!!!!!!
Benutzeravatar
hyperjojo
Beiträge: 801
Registriert: 26 Jul 2009, 02:26

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von hyperjojo »

hi,
Bernie137 hat geschrieben: 19 Jun 2018, 15:38Das Ganze kann man dann noch in ein Script (Batchdatei) packen:
habe deinen Code noch ein bisschen angepasst, ähnliches hatte ich in der Vergangenheit schon am Laufen, dein Code gefällt mir aber besser.

Code: Alles auswählen

@echo off
setlocal
Set Scriptpfad=%~d0%~p0
Set plink=%Scriptpfad%plink.exe
Set csvPfad=%Scriptpfad%devices.csv
Set backupPfad=%Scriptpfad%backups
Set month=%DATE:~3,2%
Set day=%DATE:~0,2%
Set year=%DATE:~6,4%
Set hour=%TIME:~0, 2%
Set minutes=%time:~3, 2%
Set seconds=%time:~6, 2%

if not exist "%backupPfad%" mkdir %backupPfad%

for /F "usebackq tokens=1-5 eol=# delims=; " %%i in (%csvPfad%) do (
	%plink% -P %%m -pw %%l %%k@%%j readscript > "%backupPfad%\%%i_%year%-%month%-%day%_%hour%-%minutes%-%seconds%.lcs"
	%plink% -P %%m -pw %%l %%k@%%j readconfig > "%backupPfad%\%%i_%year%-%month%-%day%_%hour%-%minutes%-%seconds%.lcf")
endlocal
Änderungen:
- Der Port wird als zusätzliche Spalte in der csv-Datei abgefragt, da ich i.d.R. Router habe, bei denen nicht der Default-SSH Port verwendet wird.
- Die Files/Ordner liegen automatisch im Root-verzeichnis der .bat-Datei.
- Zeitstempel im Dateinamen, damit (bei mehrmaligem ausführen pro Tag) nicht die bestehende Datei überschrieben wird
- Überprüfung, ob das Backup-Verzeichnis existiert, ansonsten anlegen.

Danke für die Vorlage!

Gruß hyperjojo
Benutzeravatar
Bernie137
Beiträge: 1700
Registriert: 17 Apr 2013, 21:50
Wohnort: zw. Chemnitz und Annaberg-Buchholz

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von Bernie137 »

Hallo Hyperjojo,
habe deinen Code noch ein bisschen angepasst, ähnliches hatte ich in der Vergangenheit schon am Laufen, dein Code gefällt mir aber besser.
Das freut mich und genau dafür habe ich es ja auch gepostet.
- Der Port wird als zusätzliche Spalte in der csv-Datei abgefragt, da ich i.d.R. Router habe, bei denen nicht der Default-SSH Port verwendet wird.
Die Idee den Port noch mit aufzunehmen ist gut.
- Die Files/Ordner liegen automatisch im Root-verzeichnis der .bat-Datei.
Bei mir auch. Trotzdem gebe ich bei den Variablen explizite Pfade an, weil ich damit schon Probleme über den Taskplaner hatte.

Was einfach noch fehlt und ich mangels Zeit noch nicht gelöst habe ist, dass wenn man ein weiteres Gerät in der CSV hinzufügt, ich dann immer einmal die Batch von Hand starten muss um die SSH-RSA Meldung zu bestätigen. Es wäre hübscher, die Batch würde es gleich mit lösen.
ssh-rsa_key.jpg
Gruß Bernie
Du hast keine ausreichende Berechtigung, um die Dateianhänge dieses Beitrags anzusehen.
Man lernt nie aus.
Benutzeravatar
Bernie137
Beiträge: 1700
Registriert: 17 Apr 2013, 21:50
Wohnort: zw. Chemnitz und Annaberg-Buchholz

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von Bernie137 »

Nun hat es mir selbst keine Ruhe mehr gelassen, da ich es schon immer angehen wollte habe ich es wie folgt gelöst mit folgender zusatzlicher Zeile:

Code: Alles auswählen

echo y | %plink% -ssh -pw %%l %%k@%%j "exit"
im Zusammenhang dann so:

Code: Alles auswählen

@echo off
setlocal
SET plink=C:\putty\plink.exe
SET csvPfad=C:\putty\devices.csv
SET backupPfad=C:\putty\backups
Set day=%DATE:~0,2%
Set mm=%DATE:~3,2%
Set dd=%DATE:~0,2%
Set yyyy=%DATE:~6,4%

for /F "usebackq tokens=1-4 eol=# delims=; " %%i in (%csvPfad%) do (
	echo y | %plink% -ssh -pw %%l %%k@%%j "exit"
	%plink% -pw %%l %%k@%%j readscript > "%backupPfad%\%%i_%yyyy%%mm%%dd%.lcs"
	%plink% -pw %%l %%k@%%j readconfig > "%backupPfad%\%%i_%yyyy%%mm%%dd%.lcf")
endlocal
Gruß Bernie
Man lernt nie aus.
itf009
Beiträge: 5
Registriert: 09 Mai 2018, 16:17

Re: Konfigurationsscript mittels TFTP auslesen

Beitrag von itf009 »

Moin,

Funktioniert das Script auch mit einem Switch ?

%plink% -pw %%l %%k@%%j readconfig > "%backupPfad%\%%i_%yyyy%%mm%%dd%.xml


Beste Grüsse
Antworten